c++ - In CMake, how can I test if the compiler is Clang?

Collectives™ on Stack Overflow

Find centralized, trusted content and collaborate around the technologies you use most.

Learn more about Collectives

Teams

Q&A for work

Connect and share knowledge within a single location that is structured and easy to search.

Learn more about Teams

We have a set of cross-platform CMake build scripts , and we support building with Visual C++ and GCC .

We're trying out Clang , but I can't figure out how to test whether or not the compiler is Clang with our CMake script.

What should I test to see if the compiler is Clang or not? We're currently using MSVC and CMAKE_COMPILER_IS_GNU<LANG> to test for Visual C++ and GCC, respectively.

You can set compiler by setting CMAKE_C_COMPILER and CMAKE_CXX_COMPILER to path to clang or clang++. +1 for clang. – Zaffy Apr 6, 2012 at 19:15 @BasileStarynkevitch Since we supported MSVC, we needed to detect Clang so we knew whether to turn on the GCC-like options, or the MSVC-like options. It's been too long for me to remember, but it's also certainly possible we were using options not supported by Clang as well. – leedm777 Jan 5, 2015 at 14:39 @BasileStarynkevitch - Clang pretends to be both


    __GNUC__

and


    _MSC_VER

, but it can't consume the same programs as either compiler. Detecting LLVM Clang and Apple Clang is crucial to ensuring the code compiles and executes as expected. I'm so tired of dealing with Clang's BS we just break the compile on Windows . We've adopted the policy of let users complain to LLVM so the Clang devs change their behavior. Also see How to tell Clang to stop pretending to be other compilers? – jww Sep 13, 2016 at 16:29

A reliable check is to use the CMAKE_<LANG>_COMPILER_ID variables. E.g., to check the C++ compiler:

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  # using Clang
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  # using GCC
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "Intel")
  # using Intel C++
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  # using Visual Studio C++
endif()
These also work correctly if a compiler wrapper like ccache is used.
As of CMake 3.0.0 the CMAKE_<LANG>_COMPILER_ID value for Apple-provided Clang is now AppleClang. To test for both the Apple-provided Clang and the regular Clang use the following if condition:
if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  # using regular Clang or AppleClang
endif()
Also see the AppleClang policy description.
CMake 3.15 has added support for both the clang-cl and the regular clang front end. You can determine the front end variant by inspecting the variable CMAKE_<LANG>_COMPILER_FRONTEND_VARIANT:
if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  if (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC")
    # using clang with clang-cl front end
  elseif (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "GNU")
    # using clang with regular front end
  endif()
endif()
                The cmake documentation states "This is used in determining the compiler and is subject to change". Otherwise, it would be perfect :-(
– leedm777
                Apr 7, 2012 at 15:19
                As of CMake 2.8.10, this variable is (finally!) documented. See: cmake.org/cmake/help/v2.8.10/…
– Nick Hutchinson
                Nov 19, 2012 at 1:07
                Note that the CMAKE_CXX_COMPILER_ID variable is only available after the command project(Foo CXX).
– waldyrious
                Jun 1, 2016 at 18:28
                And for flags that both gcc and clang accept, I use if (CMAKE_CXX_COMPILER_ID MATCHES "Clang|GNU") ... endif()
– Fred Schoen
                Jun 7, 2017 at 7:59
                If you are confused why you cannot detect AppleClang specifically, @sakra indicates that cmake 3.0.0 released AppleClang.  However, just because cmake --version reports equal to or higher is not enough -- you have to cmake_minimum_required(VERSION 3.0.0) in order for the 3.0.0 standards to be used!
– svenevs
                Jun 9, 2017 at 0:56
This is a slightly more detailed answer for cmake newbies, modified from sakra's answer. The minimum version of 3.1 seems to be important as it changes the way CMake processes the quoted "MSVC" string (according to policy CMP0054).
cmake_minimum_required(VERSION 3.1)
project(MyProject CXX)
if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
  MESSAGE("Clang")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  MESSAGE("GNU")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel")
  MESSAGE("Intel")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()
If your cmake_minimum_required VERSION is less than 3.1, then you have to use quoted variable to determine compiler, if together with STREQUAL command, i.e.
if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()
Or, if you don't like quoted stuff, you can use MATCHES command:
if (CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  MESSAGE("MSVC")
endif()
And if you specify cmake_minimum_required VERSION >= 3.1, then you can happily use STREQUAL without quotes:
if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()
the cmake 3.1 version issue, is documented here: https://cmake.org/cmake/help/latest/policy/CMP0054.html
Just to avoid any misspelling problem, I am using Case-insensitive compare, like:
string( TOLOWER "${CMAKE_CXX_COMPILER_ID}" COMPILER_ID )
if (COMPILER_ID STREQUAL "clang")
    set(IS_CLANG_BUILD true)
else ()
    set(IS_CLANG_BUILD false)
endif ()
For making the regex of MATCHES case-insensitive, I tried everything here without success (doesn't seem to be supported in CMake).
                indeed, as today, case insensitive matching it is not possible cmake.org/pipermail/cmake/2017-May/065432.html
– fferri
                Dec 8, 2017 at 18:02
You can test for Clang and it's frontends like this:
if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  if (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC") # clang-cl
    # ...
  elseif (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "GNU") # clang native
    # ...
  endif()
elseif (CMAKE_CXX_COMPILER_ID MATCHES "Clang|GNU") # both
    # ...
endif()
CMAKE_CXX_COMPILER_FRONTEND_VARIANT requires CMake v3.14+.
        Thanks for contributing an answer to Stack Overflow!
Please be sure to answer the question. Provide details and share your research!
But avoid …
Asking for help, clarification, or responding to other answers.
Making statements based on opinion; back them up with references or personal experience.
To learn more, see our tips on writing great answers.